# Initialize ######################################################################################

Include                             ( cotire        OPTIONAL RESULT_VARIABLE HAS_COTIRE )
Include                             ( pedantic      OPTIONAL RESULT_VARIABLE HAS_PEDANTIC )
Include                             ( strip_symbols OPTIONAL RESULT_VARIABLE HAS_STRIP_SYMBOLS )

# Interface Library ###############################################################################

If                                  ( "${CPPCORE_CONVERT_CAST}" STREQUAL "abort" )
    Set                                 ( CPPCORE_CONVERT_CAST_ABORT 1 )
ElseIf                              ( "${CPPCORE_CONVERT_CAST}" STREQUAL "throw" )
    Set                                 ( CPPCORE_CONVERT_CAST_THROW 1 )
EndIf                               ( )

Set                         	    ( CPPCORE_GENERATED_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/generated )
Configure_File                      ( ${CMAKE_CURRENT_SOURCE_DIR}/../cmake/config.h.in
                                      ${CPPCORE_GENERATED_INCLUDE_DIR}/cppcore/config.h )
Set                                 ( CPPCORE_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../include )
Add_Library                         ( cppcore INTERFACE )
Target_Include_Directories          ( cppcore
                                      INTERFACE
                                        $<BUILD_INTERFACE:${CPPCORE_INCLUDE_DIR}>
                                        $<BUILD_INTERFACE:${CPPCORE_GENERATED_INCLUDE_DIR}>
                                        $<INSTALL_INTERFACE:${CPPCORE_INSTALL_DIR_INCLUDE}> )

# Install #########################################################################################

Set                                 ( CPPCORE_HAS_EXPORT False PARENT_SCOPE )

# Header
If                                  ( CPPCORE_INSTALL_HEADER )
    Set                                 ( CPPCORE_HAS_EXPORT True PARENT_SCOPE )
    Install                             ( FILES ${CPPCORE_INCLUDE_DIR}/cppcore.h
                                          DESTINATION ${CPPCORE_INSTALL_DIR_INCLUDE} )
    Install                             ( DIRECTORY ${CPPCORE_INCLUDE_DIR}/cppcore
                                          DESTINATION ${CPPCORE_INSTALL_DIR_INCLUDE} )
    Install                             ( DIRECTORY ${CPPCORE_GENERATED_INCLUDE_DIR}/cppcore
                                          DESTINATION ${CPPCORE_INSTALL_DIR_INCLUDE} )
    Install                             ( TARGETS cppcore
                                          EXPORT cppcore
                                          DESTINATION ${CPPCORE_INSTALL_DIR_INCLUDE} )
EndIf                               ( )