emptyproject/projects/helloworld/CMakeLists.txt

# Initialize CMake ################################################################################

CMake_Minimum_Required ( VERSION 3.12.0 FATAL_ERROR )

# CMAKE_BUILD_TYPE
If ( NOT CMAKE_BUILD_TYPE )
    Set ( CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build!" FORCE )
EndIf ( )
Set_Property ( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS Debug Release RelWithDebInfo MinSizeRel )

# CMAKE_MODULE_PATH
If ( EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/cmake/" )
    Set ( CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/" )
EndIf ( )

If ( EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules/cmake" )
    Set ( CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules/cmake" )
EndIf ( )

# Project #########################################################################################

Include ( GNUInstallDirs )

Include ( ${CMAKE_CURRENT_SOURCE_DIR}/cmake/helloworld-options.cmake )
Include ( ${CMAKE_CURRENT_SOURCE_DIR}/cmake/helloworld-const.cmake )
Include ( ${CMAKE_CURRENT_SOURCE_DIR}/cmake/helloworld-var.cmake )

Project ( ${HELLOWORLD_PROJECT_NAME}
          DESCRIPTION "${HELLOWORLD_PROJECT_DESCRIPTION}"
          VERSION "${HELLOWORLD_VERSION}" )

Include ( CTest )

# Initialize ######################################################################################

Include ( cotire OPTIONAL RESULT_VARIABLE HAS_COTIRE )
Include ( pedantic OPTIONAL RESULT_VARIABLE HAS_PEDANTIC )
Include ( cmake_tests OPTIONAL RESULT_VARIABLE HAS_CMAKE_TESTS )
Include ( strip_symbols OPTIONAL RESULT_VARIABLE HAS_STRIP_SYMBOLS )

Find_Package ( GTest QUIET )
Find_Package ( Sanitizers QUIET )

Message ( FATAL_ERROR "Please configure the dependencies of this project!" )
Find_Package ( libhelloworld REQUIRED ${HELLOWORLD_FIND_PACKAGE_EXTRA_ARGS} )

# Object Library ##################################################################################

Set ( HELLOWORLD_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/src" )
Set ( HELLOWORLD_INCLUDE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/src" )
Set ( HELLOWORLD_MAIN_FILE "${HELLOWORLD_SOURCE_DIR}/main.cpp" )

File ( GLOB_RECURSE HELLOWORLD_HEADER_FILES "${HELLOWORLD_INCLUDE_DIR}/*.h" )
File ( GLOB_RECURSE HELLOWORLD_INLINE_FILES "${HELLOWORLD_INCLUDE_DIR}/*.inl" )
File ( GLOB_RECURSE HELLOWORLD_SOURCE_FILES "${HELLOWORLD_SOURCE_DIR}/*.cpp" )

File ( GLOB_RECURSE HELLOWORLD_TEST_HEADER_FILES "${HELLOWORLD_INCLUDE_DIR}/*.test.h" )
File ( GLOB_RECURSE HELLOWORLD_TEST_INLINE_FILES "${HELLOWORLD_INCLUDE_DIR}/*.test.inl" )
File ( GLOB_RECURSE HELLOWORLD_TEST_SOURCE_FILES "${HELLOWORLD_SOURCE_DIR}/*.test.cpp" )

ForEach ( TEST_FILE IN LISTS HELLOWORLD_TEST_HEADER_FILES )
    List ( REMOVE_ITEM HELLOWORLD_HEADER_FILES "${TEST_FILE}" )
EndForEach ( )

ForEach ( TEST_FILE IN LISTS HELLOWORLD_TEST_INLINE_FILES )
    List ( REMOVE_ITEM HELLOWORLD_INLINE_FILES "${TEST_FILE}" )
EndForEach ( )

List ( REMOVE_ITEM HELLOWORLD_SOURCE_FILES "${HELLOWORLD_MAIN_FILE}" )
ForEach ( TEST_FILE IN LISTS HELLOWORLD_TEST_SOURCE_FILES )
    List ( REMOVE_ITEM HELLOWORLD_SOURCE_FILES "${TEST_FILE}" )
EndForEach ( )

Add_Library (
    helloworld-objects
    OBJECT
        ${HELLOWORLD_HEADER_FILES}
        ${HELLOWORLD_INLINE_FILES}
        ${HELLOWORLD_SOURCE_FILES} )
Target_Include_Directories (
    helloworld-objects
    PUBLIC
        $<BUILD_INTERFACE:${HELLOWORLD_INCLUDE_DIR}>
        $<INSTALL_INTERFACE:${HELLOWORLD_INSTALL_DIR_INCLUDE}> )
Target_Link_Libraries (
    helloworld-objects
    PUBLIC
        libhelloworld::libhelloworld-shared )

# Executable ######################################################################################

Add_Executable ( helloworld "${HELLOWORLD_MAIN_FILE}" )
Target_Link_Libraries (
    helloworld
    PUBLIC
        helloworld-objects )

# Tests ###########################################################################################

If ( GTest_FOUND )
    ForEach ( FILE IN LISTS HELLOWORLD_TEST_SOURCE_FILES )

        # Add Test
        File ( RELATIVE_PATH RELFILE "${HELLOWORLD_SOURCE_DIR}" "${FILE}" )
        Get_Filename_Component ( TEST_DIR "${RELFILE}" DIRECTORY )
        Get_Filename_Component ( TEST_NAME "${RELFILE}" NAME_WE )
        Set ( TEST_NAME "${TEST_DIR}/${TEST_NAME}" )
        String ( REPLACE ".test" "" TEST_NAME "${TEST_NAME}" )
        String ( REPLACE "\\" "-" TEST_NAME "${TEST_NAME}" )
        String ( REPLACE "/" "-" TEST_NAME "${TEST_NAME}" )
        String ( REPLACE "_" "-" TEST_NAME "${TEST_NAME}" )
        Set ( TEST_NAME "test-${TEST_NAME}" )

        Add_Executable ( ${TEST_NAME}
                         EXCLUDE_FROM_ALL
                            ${HELLOWORLD_TEST_HEADER_FILES}
                            ${HELLOWORLD_TEST_INLINE_FILES}
                            ${FILE} )
        Target_Link_Libraries ( ${TEST_NAME}
                                PUBLIC
                                    helloworld-objects
                                    GTest::Main )

        # Sanitizers
        If ( Sanitizers_FOUND )
            Add_Sanitizers ( ${TEST_NAME} )
        EndIf ( )

        # pedantic
        If ( HAS_PEDANTIC )
            Pedantic_Apply_Flags_Target ( ${TEST_NAME} ALL )
        EndIf ( )

        # test
        If ( HAS_CMAKE_TESTS )
            Add_CMake_Test ( NAME ${TEST_NAME} TARGET ${TEST_NAME} GROUP gedt )
        Else ( )
            Add_Test ( NAME ${TEST_NAME} COMMAND ${TEST_NAME} WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR} )
        EndIf ( )
    EndForEach ( )
EndIf ( )

# Optimization ####################################################################################

# sanitizers
If ( Sanitizers_FOUND )
    Add_Sanitizers ( helloworld-objects )
    Add_Sanitizers ( helloworld )
EndIf ( )

# pedantic
If ( HAS_PEDANTIC )
    Pedantic_Apply_Flags_Target ( helloworld-objects ALL )
    Pedantic_Apply_Flags_Target ( helloworld ALL )
EndIf ( )

# cotire
If ( HAS_COTIRE )
    Cotire ( helloworld-objects )
    Cotire ( helloworld )
EndIf ( )

# Install #########################################################################################

# Executable
Install ( TARGETS helloworld
          DESTINATION ${HELLOWORLD_INSTALL_DIR_BIN} )

# Debug
If ( HAS_STRIP_SYMBOLS AND NOT HELLOWORLD_NO_STRIP )
    Strip_Symbols ( helloworld HELLOWORLD_DBG_FILE )
    If ( HELLOWORLD_INSTALL_DEBUG )
        Install ( FILES ${HELLOWORLD_DBG_FILE}
                  DESTINATION ${HELLOWORLD_INSTALL_DIR_LIB} )
    EndIf ( )
EndIf ( )